import:
	ch.njol.skript.Skript
	ch.njol.skript.variables.Variables
	
	java.lang.Number

	java.util.TreeSet
	java.util.Map$Entry

local effect set variable %object% to %object% in %event%:
	trigger:
		set {_name} to expr-1.getName().toString(expr-3)
		Variables.setVariable({_name}, expr-2, expr-3 and expr-1.isLocal())
		
local expression variable %objects% in %event%:
	return type: object
	get:
		set {_name} to expr-1.getName().toString(expr-2)
		return Variables.getVariable({_name}, expr-2 and expr-1.isLocal())

expression (1¦(highest|top)|2¦(lowest|last)) %integer% values of %objects% (with format|formatted) %string%:
	return type: strings
	get:
		set {_treemap} to variable raw exprs-2 in event
		
		if parse mark = 1:
			set {_set} to new TreeSet(Entry.comparingByValue().reversed())
		else:
			set {_set} to new TreeSet(Entry.comparingByValue())
			
		loop ...{_treemap}.entrySet():
			set {_val} to loop-value.getValue()
			{_val} is instance of Number
			loop-value.setValue({_val}.doubleValue())
			{_set}.add(loop-value)
		
		loop ...{_set}:
			add 1 to {_n}
			
			set {_key} to loop-value.getKey()
			set {_l::%{_n}%} to expr-3.replace("@pos" and "%{_n}%").replace("@index" and "%{_key}%").replace("@value" and "%{_treemap}.get({_key})%")
			
			{_n} = expr-1
			stop loop
			
		return {_l::*}